forth.wat

   1 (;  This program is free software: you can redistribute it and/or modify
   2     it under the terms of the GNU General Public License as published by
   3     the Free Software Foundation, either version 3 of the License, or
   4     (at your option) any later version.
   5
   6     This program is distributed in the hope that it will be useful,
   7     but WITHOUT ANY WARRANTY; without even the implied warranty of
   8     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9     GNU General Public License for more details.
  10
  11     You should have received a copy of the GNU General Public License
  12     along with this program.  If not, see <http://www.gnu.org/licenses/>. ;)
  13 (module
  14   (type $FUNCSIGi   (func (result i32)))
  15   (type $FUNCSIGii  (func (param i32)))
  16   (type $FUNCSIGiii (func))
  17   (type $FUNCSIGiv  (func (param i32 i32) (result i32)))
  18   (type $FUNCSIG$v  (func (param i32) (result i32)))
  19   (type $FUNCSIG$vi (func (param i32 i32 i32) (result i32)))
  20   (import "env" "pop" (func $pop (result i32)))
  21   (import "env" "push" (func $push (param i32)))
  22   (import "env" "rinit" (func $rinit))
  23   (import "env" "rpop" (func $rpop (result i32)))
  24   (import "env" "rpush" (func $rpush (param i32)))
  25   (import "env" "sys_read" (func $sys_read (param i32 i32 i32) (result i32)))
  26   (import "env" "sys_fetch" (func $sys_fetch (param i32 i32) (result i32)))
  27   (import "env" "sys_listen" (func $sys_listen (param i32) (result i32)))
  28   (import "env" "sys_write" (func $sys_write (param i32 i32 i32) (result i32)))
  29   (import "env" "sys_echo" (func $sys_echo (param i32)))
  30   (import "env" "sys_echochar" (func $sys_echochar (param i32)))
  31   (import "env" "sys_reflect" (func $sys_reflect (param i32)))
  32   (import "env" "vocab_get" (func $vocab_get (param i32 i32) (result i32)))
  33   (import "env" "vocab_set" (func $vocab_set (param i32 i32 i32) (result i32)))
  34   (import "env" "is_whitespace" (func $is_whitespace (param i32) (result i32)))
  35   (import "env" "sys_parsenum" (func $sys_parsenum (param i32 i32 i32) (result i32)))
  36   (import "env" "sys_stack" (func $sys_stack))
  37   (import "env" "sys_words" (func $sys_words))
  38   (table (;0;) 0 anyfunc)
  39   (memory $0 1)
  40   (; String Belt                       ;) ;; 0x0000 Size: 8192
  41   (global $wordbelt i32 (i32.const 8192)) ;; 0x2000 Size: 4096
  42   (global $inbuf i32 (i32.const 12288))   ;; 0x3000 Size: 2048
  43   (global $inbuf_size i32 (i32.const 12292))
  44   (global $inbuf_data i32 (i32.const 12296))
  45   (global $kvars i32 (i32.const 14336))   ;; 0x3800 Size: 2048
  46   (data (i32.const 12288) "\f8\07\00\00") ;; 2040 len
  47   (data (i32.const 14336) "\28\41\00\00") ;; MODE
  48   (data (i32.const 14340) "\04\42\00\00") ;; HERE
  49   (data (i32.const 14344) "\00\40\00\00") ;; START
  50   (data (i32.const 14348) "\0a\00\00\00") ;; BASE
  51   (data (i32.const 14352) "\00\00\00\00") ;; STRINGBELT_TAIL
  52   (data (i32.const 14356) "\00\00\00\00") ;; STRINGBELT_HEAD
  53   (data (i32.const 14360) "\00\20\00\00") ;; WORDBELT_TAIL
  54   (data (i32.const 14364) "\00\20\00\00") ;; WORDBELT_HEAD
  55   (data (i32.const 14368) "\00\00\00\00") ;; CHANNEL
  56   (; Quit ;)
  57   (data (i32.const 16384) "\03\00\00\00") ;; RINIT xt
  58   (data (i32.const 16388) "\10\40\00\00") ;; INTERPRET xt
  59   (data (i32.const 16392) "\12\00\00\00") ;; JMP xt
  60   (data (i32.const 16396) "\00\40\00\00") ;; quit location (16384)
  61   (; Interpret ;)
  62   (data (i32.const 16400) "\74\40\00\00") ;; WORD xt (16500)
  63   (data (i32.const 16404) "\06\00\00\00") ;; DUP
  64   (data (i32.const 16408) "\0e\00\00\00") ;; JZ:
  65   (data (i32.const 16412) "\38\40\00\00") ;; INTERP-END addr (16444)
  66   (data (i32.const 16416) "\02\00\00\00") ;; LIT xt
  67   (data (i32.const 16420) "\00\38\00\00") ;; MODE addr (14336)
  68   (data (i32.const 16424) "\0a\00\00\00") ;; @ (fetch) xt
  69   (data (i32.const 16428) "\0c\00\00\00") ;; EXECUTE xt
  70   (data (i32.const 16432) "\0d\00\00\00") ;; NOOP xt
  71   (data (i32.const 16436) "\01\00\00\00") ;; RET
  72   (data (i32.const 16440) "\10\00\00\00") ;; DROP  <-- INTERP-END
  73   (data (i32.const 16444) "\10\00\00\00") ;; DROP
  74   (data (i32.const 16448) "\19\00\00\00") ;; BYE
  75   (; Word ;)
  76   (data (i32.const 16500) "\14\00\00\00") ;; WORDSTART
  77   (data (i32.const 16504) "\05\00\00\00") ;; KEY  <-- KEYLOOP
  78   (data (i32.const 16508) "\06\00\00\00") ;; DUP
  79   (data (i32.const 16512) "\18\00\00\00") ;; J-1: 18
  80   (data (i32.const 16516) "\f0\40\00\00") ;; addr of WORDEND
  81   (data (i32.const 16520) "\11\00\00\00") ;; WS?
  82   (data (i32.const 16524) "\0f\00\00\00") ;; JNZ:
  83   (data (i32.const 16528) "\bc\40\00\00") ;; addr of KEYDROP
  84   (data (i32.const 16532) "\02\00\00\00") ;; LIT
  85   (data (i32.const 16536) "\5c\00\00\00") ;; 92 (\ character)
  86   (data (i32.const 16540) "\25\00\00\00") ;; =?
  87   (data (i32.const 16544) "\0e\00\00\00") ;; JZ:
  88   (data (i32.const 16548) "\e4\40\00\00") ;; addr of DOCHAR
  89   (data (i32.const 16552) "\10\00\00\00") ;; DROP
  90   (data (i32.const 16556) "\94\41\00\00") ;; DO-BACKSLASH (continue using this wbuf we started)
  91   (data (i32.const 16560) "\0d\00\00\00") ;; NOOP
  92   (data (i32.const 16564) "\12\00\00\00") ;; JMP:
  93   (data (i32.const 16568) "\74\40\00\00") ;; addr of KEYLOOP-1 (get a new wbuf, call to wbuf+1 ate ours)
  94   (data (i32.const 16572) "\10\00\00\00") ;; DROP <-- KEYDROP
  95   (data (i32.const 16576) "\12\00\00\00") ;; JMP:
  96   (data (i32.const 16580) "\78\40\00\00") ;; addr of KEYLOOP
  97   (data (i32.const 16584) "\05\00\00\00") ;; KEY <-- WORDLOOP
  98   (data (i32.const 16588) "\11\00\00\00") ;; WS?
  99   (data (i32.const 16592) "\0f\00\00\00") ;; JNZ:
 100   (data (i32.const 16596) "\f0\40\00\00") ;; addr of WORDEND
 101   (data (i32.const 16600) "\06\00\00\00") ;; DUP
 102   (data (i32.const 16604) "\18\00\00\00") ;; J-1:
 103   (data (i32.const 16608) "\f0\40\00\00") ;; addr of WORDEND
 104   (data (i32.const 16612) "\13\00\00\00") ;; WORDPUTC <-- DOCHAR
 105   (data (i32.const 16616) "\12\00\00\00") ;; JMP:
 106   (data (i32.const 16620) "\c8\40\00\00") ;; addr of WORDLOOP
 107   (data (i32.const 16624) "\10\00\00\00") ;; DROP <-- WORDEND
 108   (data (i32.const 16628) "\17\00\00\00") ;; WORDFINISH
 109   (data (i32.const 16632) "\01\00\00\00") ;; RET
 110   (; Exec Mode ;)
 111   (data (i32.const 16680) "\1e\00\00\00") ;; DUP2
 112   (data (i32.const 16684) "\15\00\00\00") ;; DICT_GET
 113   (data (i32.const 16688) "\06\00\00\00") ;; DUP
 114   (data (i32.const 16692) "\0e\00\00\00") ;; JZ:
 115   (data (i32.const 16696) "\4c\41\00\00") ;; donum -1 (16716)
 116   (data (i32.const 16700) "\1f\00\00\00") ;; ROT
 117   (data (i32.const 16704) "\20\00\00\00") ;; DROP2
 118   (data (i32.const 16708) "\0c\00\00\00") ;; EXECUTE
 119   (data (i32.const 16712) "\01\00\00\00") ;; RET
 120   (data (i32.const 16716) "\10\00\00\00") ;; DROP (xt from dictionary)
 121   (data (i32.const 16720) "\16\00\00\00") ;; NUMBER <-- donum, pushes NUM, UNPARSED
 122   (data (i32.const 16724) "\06\00\00\00") ;; DUP
 123   (data (i32.const 16728) "\0f\00\00\00") ;; JNZ:
 124   (data (i32.const 16732) "\68\41\00\00") ;; donum_err (16744)
 125   (data (i32.const 16736) "\10\00\00\00") ;; DROP
 126   (data (i32.const 16740) "\01\00\00\00") ;; RET
 127   (data (i32.const 16744) "\10\00\00\00") ;; PARSE_ERR <-- donum_err
 128   (data (i32.const 16748) "\10\00\00\00") ;; ( DROP DROP )
 129   (data (i32.const 16752) "\19\00\00\00") ;; BYE
 130   (; Do Backslash ;)
 131   (data (i32.const 16788) "\05\00\00\00") ;; KEY
 132   (data (i32.const 16792) "\11\00\00\00") ;; WS?
 133   (data (i32.const 16796) "\0f\00\00\00") ;; JNZ:
 134   (data (i32.const 16800) "\c8\41\00\00") ;; addr of keypump + 3
 135   (data (i32.const 16804) "\cc\40\00\00") ;; WORDLOOP + 1
 136   (data (i32.const 16808) "\28\41\00\00") ;; EXECUTE-MODE
 137   (data (i32.const 16812) "\01\00\00\00") ;; RET
 138   (; Do Comment ;)
 139   (data (i32.const 16828) "\18\00\00\00") ;; j-1: <-- keypump
 140   (data (i32.const 16832) "\e0\41\00\00") ;; addr of end
 141   (data (i32.const 16836) "\05\00\00\00") ;; KEY
 142   (data (i32.const 16840) "\02\00\00\00") ;; LIT
 143   (data (i32.const 16844) "\0a\00\00\00") ;; 10 (line feed)
 144   (data (i32.const 16848) "\25\00\00\00") ;; =?
 145   (data (i32.const 16852) "\0e\00\00\00") ;; JZ:
 146   (data (i32.const 16856) "\bc\41\00\00") ;; addr of keypump
 147   (data (i32.const 16860) "\10\00\00\00") ;; DROP
 148   (data (i32.const 16864) "\01\00\00\00") ;; RET
 149
 150   (export "memory" (memory $0))
 151   (export "main" (func $main))
 152   (func $main (result i32)
 153     call $interpret
 154   )
 155   (func $interpret (result i32)
 156     (local $here i32)
 157     (local $eax i32)
 158     (local $esi i32)
 159     (local $inbuf_head i32)
 160     (local $stringbelt_tail i32)
 161     (local $stringbelt_head i32)
 162     (local $wordbelt_tail i32)
 163     (local $wordbelt_head i32)
 164     (local $channel i32)
 165     i32.const 14340
 166     i32.load
 167     set_local $here
 168     i32.const 14344
 169     i32.load
 170     set_local $esi
 171     get_global $inbuf_data
 172     set_local $inbuf_head
 173     i32.const 14352
 174     i32.load
 175     set_local $stringbelt_tail
 176     i32.const 14356
 177     i32.load
 178     set_local $stringbelt_head
 179     i32.const 14360
 180     i32.load
 181     set_local $wordbelt_tail
 182     i32.const 14364
 183     i32.load
 184     set_local $wordbelt_head
 185     i32.const 14368
 186     i32.load
 187     set_local $channel
 188     block $bye
 189     loop $next
 190       get_local $esi
 191       get_local $esi
 192       i32.const 4
 193       i32.add
 194       set_local $esi
 195       i32.load
 196       set_local $eax
 197       loop $execloop
 198       block $default block $op0 block $ret block $lit block $rinit
 199       block $word block $key block $dup block $plus block $noop2 block $emit
 200       block $fetch block $set block $execute block $noop block $jz block $jnz
 201       block $drop block $wsbool block $jmp block $wordputc block $wordstart
 202       block $dictget block $parsenum block $wordfinish block $jneg1 block $swap
 203       block $words block $here block $dictset block $dup2 block $rot block $drop2
 204       block $comma block $subtract block $keychan block $sethere block $eqbool
 205       block $echostring block $strstart block $strput block $strend
 206         get_local $eax
 207         br_table $op0 $ret (;2;)$lit $rinit (;4;)$word $key (;6;)$dup $plus
 208         (;8;)$jmp $emit (;10;)$fetch $set (;12;)$execute $noop (;14;)$jz $jnz
 209         (;16;)$drop $wsbool (;18;)$jmp $wordputc (;20;)$wordstart $dictget
 210         (;22;)$parsenum $wordfinish (;24;)$jneg1 $bye (;26;)$swap $words
 211         (;28;)$here $dictset (;30;)$dup2 $rot (;32;)$drop2 $comma
 212         (;34;)$subtract $keychan (;36;)$sethere $eqbool (;38;)$echostring $strstart
 213         (;40;)$strput $strend $default
 214       end ;; strend
 215         get_local $stringbelt_tail
 216         get_local $stringbelt_head
 217         get_local $stringbelt_tail
 218         i32.const 4
 219         i32.add
 220         i32.sub
 221         tee_local $eax (; n bytes ;)
 222         i32.store
 223         (; align to 32-bit ;)
 224         get_local $stringbelt_head
 225         i32.const 3
 226         i32.add
 227         i32.const 8188
 228         i32.and
 229         set_local $stringbelt_head
 230         (; /align ;)
 231         get_local $stringbelt_tail
 232         i32.const 4
 233         i32.add
 234         call $push
 235         get_local $eax
 236         call $push
 237         br $next
 238       end ;; strput
 239         block $sbhasspace2
 240           get_local $stringbelt_head
 241           get_global $wordbelt
 242           i32.lt_u
 243           br_if $sbhasspace2
 244           i32.const 0
 245           tee_local $stringbelt_head
 246           get_local $stringbelt_tail
 247           i32.load
 248           i32.store
 249           get_local $stringbelt_head
 250           i32.const 4
 251           i32.add
 252           set_local $stringbelt_head
 253           get_local $stringbelt_tail
 254           i32.const 4
 255           i32.add
 256           set_local $stringbelt_tail
 257           loop $copystringtostart
 258             get_local $stringbelt_head
 259             get_local $stringbelt_tail
 260             i32.load16_u
 261             i32.store16
 262             get_local $stringbelt_head
 263             i32.const 2
 264             i32.add
 265             set_local $stringbelt_head
 266             get_local $stringbelt_tail
 267             i32.const 2
 268             i32.add
 269             tee_local $stringbelt_tail
 270             get_global $wordbelt
 271             i32.le_u
 272             br_if $copystringtostart
 273           end
 274           i32.const 0
 275           set_local $stringbelt_tail
 276         end
 277         get_local $stringbelt_head
 278         call $pop
 279         i32.store16
 280         get_local $stringbelt_head
 281         i32.const 2
 282         i32.add
 283         set_local $stringbelt_head
 284         br $next
 285       end ;; strstart
 286         block $sbhasspace
 287           get_local $stringbelt_head
 288           get_global $wordbelt
 289           i32.const 8
 290           i32.sub
 291           i32.le_u
 292           br_if $sbhasspace
 293           i32.const 0
 294           set_local $stringbelt_head
 295         end
 296         get_local $stringbelt_head
 297         get_local $stringbelt_head
 298         tee_local $stringbelt_tail
 299         i32.const 0
 300         i32.store
 301         i32.const 4
 302         i32.add
 303         set_local $stringbelt_head
 304         br $next
 305       end ;; echostring
 306         get_local $channel
 307         call $pop
 308         set_local $eax
 309         call $pop
 310         get_local $eax
 311         call $sys_write
 312         br $next
 313       end ;; eqbool
 314         block $equiv
 315           call $pop
 316           call $pop
 317           tee_local $eax
 318           i32.eq
 319           get_local $eax
 320           call $push
 321           br_if $equiv
 322           i32.const 0
 323           call $push
 324           br $next
 325         end
 326         i32.const 1
 327         call $push
 328         br $next
 329       end ;; sethere
 330         call $pop
 331         set_local $here
 332         br $next
 333       end ;; keychan
 334         call $pop
 335         set_local $channel
 336         br $next
 337       end ;; subtract
 338         call $pop
 339         set_local $eax
 340         call $pop
 341         get_local $eax
 342         i32.sub
 343         call $push
 344         br $next
 345       end ;; comma
 346         get_local $here
 347         call $pop
 348         i32.store
 349         get_local $here
 350         i32.const 4
 351         i32.add
 352         set_local $here
 353         br $next
 354       end ;; drop2
 355         call $pop
 356         call $pop
 357         drop
 358         drop
 359         br $next
 360       end ;; rot
 361         call $pop
 362         set_local $eax
 363         call $pop
 364         call $pop
 365         get_local $eax
 366         call $push
 367         call $push
 368         call $push
 369         br $next
 370       end ;; dup2
 371         get_local $esi
 372         call $rpush
 373         call $pop
 374         set_local $eax
 375         call $pop
 376         tee_local $esi
 377         call $push
 378         get_local $eax
 379         call $push
 380         get_local $esi
 381         call $push
 382         get_local $eax
 383         call $push
 384         call $rpop
 385         set_local $esi
 386         br $next
 387       end ;; dictset
 388         call $pop
 389         call $rpush
 390         call $pop
 391         set_local $eax
 392         call $pop
 393         get_local $eax
 394         call $rpop
 395         call $vocab_set
 396         drop
 397         br $next
 398       end ;; here
 399         get_local $here
 400         call $push
 401         br $next
 402       end ;; words
 403         call $sys_words
 404         br $next
 405       end ;; swap
 406         call $pop
 407         call $pop
 408         set_local $eax
 409         call $push
 410         get_local $eax
 411         call $push
 412         br $next
 413       end ;; jneg1
 414         block $jneg1if
 415           call $pop
 416           i32.const -1
 417           i32.eq
 418           br_if $jneg1if
 419           get_local $esi
 420           i32.const 4
 421           i32.add
 422           set_local $esi
 423           br $next
 424         end
 425         get_local $esi
 426         i32.load
 427         set_local $esi
 428         br $next
 429       end ;; wordfinish
 430         get_local $wordbelt_tail
 431         get_local $wordbelt_head
 432         get_local $wordbelt_tail
 433         i32.const 4
 434         i32.add
 435         i32.sub
 436         tee_local $eax (; n bytes ;)
 437         i32.store
 438         (; align to 32-bit ;)
 439         get_local $wordbelt_head
 440         i32.const 3
 441         i32.add
 442         i32.const 12284
 443         i32.and
 444         set_local $wordbelt_head
 445         (; /align ;)
 446         get_local $wordbelt_tail
 447         i32.const 4
 448         i32.add
 449         call $push
 450         get_local $eax
 451         call $push
 452         br $next
 453       end ;; parsenum
 454         call $pop
 455         call $rpush
 456         call $pop
 457         tee_local $eax
 458         call $rpop
 459         i32.const 14348 (; load BASE ;)
 460         i32.load
 461         call $sys_parsenum
 462         get_local $eax
 463         i32.load
 464         call $push
 465         call $push
 466         br $next
 467       end ;; dictget
 468         call $pop
 469         set_local $eax
 470         call $pop
 471         get_local $eax
 472         call $vocab_get
 473         call $push
 474         br $next
 475       end ;; wordstart
 476         block $wbhasspace
 477           get_local $wordbelt_head
 478           get_global $inbuf
 479           i32.const 8
 480           i32.sub
 481           i32.le_u
 482           br_if $wbhasspace
 483           get_global $wordbelt
 484           set_local $wordbelt_head
 485         end
 486         get_local $wordbelt_head
 487         get_local $wordbelt_head
 488         tee_local $wordbelt_tail
 489         i32.const 0
 490         i32.store
 491         i32.const 4
 492         i32.add
 493         set_local $wordbelt_head
 494         br $next
 495       end ;; wordputc
 496         block $wbhasspace2
 497           get_local $wordbelt_head
 498           get_global $inbuf
 499           i32.lt_u
 500           br_if $wbhasspace2
 501           get_global $wordbelt
 502           tee_local $wordbelt_head
 503           get_local $wordbelt_tail
 504           i32.load
 505           i32.store
 506           get_local $wordbelt_head
 507           i32.const 4
 508           i32.add
 509           set_local $wordbelt_head
 510           get_local $wordbelt_tail
 511           i32.const 4
 512           i32.add
 513           set_local $wordbelt_tail
 514           loop $copywordtostart
 515             get_local $wordbelt_head
 516             get_local $wordbelt_tail
 517             i32.load16_u
 518             i32.store16
 519             get_local $wordbelt_head
 520             i32.const 2
 521             i32.add
 522             set_local $wordbelt_head
 523             get_local $wordbelt_tail
 524             i32.const 2
 525             i32.add
 526             tee_local $wordbelt_tail
 527             get_global $inbuf
 528             i32.le_u
 529             br_if $copywordtostart
 530           end
 531           get_global $wordbelt
 532           set_local $wordbelt_tail
 533         end
 534         get_local $wordbelt_head
 535         call $pop
 536         i32.store16
 537         get_local $wordbelt_head
 538         i32.const 2
 539         i32.add
 540         set_local $wordbelt_head
 541         br $next
 542       end ;; jmp
 543         get_local $esi
 544         i32.load
 545         set_local $esi
 546         br $next
 547       end ;; wsbool
 548         call $pop
 549         tee_local $eax
 550         call $is_whitespace
 551         get_local $eax
 552         call $push
 553         call $push
 554         br $next
 555       end ;; drop
 556         call $pop
 557         drop
 558         br $next
 559       end ;; jnz
 560         block $jnzif
 561           call $pop
 562           i32.eqz
 563           br_if $jnzif
 564           get_local $esi
 565           i32.load
 566           set_local $esi
 567           br $next
 568         end
 569         get_local $esi
 570         i32.const 4
 571         i32.add
 572         set_local $esi
 573         br $next
 574       end ;; jz
 575         block $jzif
 576           call $pop
 577           i32.eqz
 578           br_if $jzif
 579           get_local $esi
 580           i32.const 4
 581           i32.add
 582           set_local $esi
 583           br $next
 584         end
 585         get_local $esi
 586         i32.load
 587         set_local $esi
 588         br $next
 589       end ;; noop
 590         br $next
 591       end ;; execute
 592         call $pop
 593         tee_local $eax
 594         i32.const 256
 595         i32.lt_u
 596         br_if $execloop
 597         get_local $esi
 598         call $rpush
 599         get_local $eax
 600         set_local $esi
 601         br $next
 602       end ;; set
 603         call $pop
 604         set_local $eax
 605         call $pop
 606         get_local $eax
 607         i32.store
 608         br $next
 609       end ;; fetch
 610         call $pop
 611         i32.load
 612         call $push
 613         br $next
 614       end ;; emit (.)
 615         call $pop
 616         call $sys_echo
 617         br $next
 618       end ;; noop2
 619         br $next
 620       end ;; plus
 621         call $pop
 622         call $pop
 623         i32.add
 624         call $push
 625         br $next
 626       end ;; dup
 627         call $pop
 628         tee_local $eax
 629         get_local $eax
 630         call $push
 631         call $push
 632         br $next
 633       end ;; key
 634         loop $key_loop
 635           block $key_read
 636             get_global $inbuf_size
 637             i32.load
 638             get_local $inbuf_head
 639             get_global $inbuf_data
 640             i32.sub
 641             i32.le_u
 642             br_if $key_read
 643             get_local $inbuf_head
 644             i32.load16_u
 645             call $push
 646             get_local $inbuf_head
 647             i32.const 2
 648             i32.add
 649             set_local $inbuf_head
 650             br $next
 651           end ;; key_read
 652           get_global $inbuf_size
 653           get_local $channel
 654           get_global $inbuf_data
 655           get_global $inbuf
 656           i32.load
 657           call $sys_read
 658           i32.store
 659           block $nullread
 660             get_global $inbuf_size
 661             i32.load
 662             i32.eqz
 663             br_if $nullread
 664             get_global $inbuf_data
 665             set_local $inbuf_head
 666             br $key_loop
 667           end ;; nullread
 668           i32.const -1 ;; <- keyval sent if sz == 0
 669           call $push
 670           br $next
 671         end ;; key_loop
 672       end ;; word
 673         br $next
 674       end ;; rinit
 675         call $rinit
 676         br $next
 677       end ;; lit
 678         get_local $esi
 679         get_local $esi
 680         i32.const 4
 681         i32.add
 682         set_local $esi
 683         i32.load
 684         call $push
 685         br $next
 686       end ;; ret
 687         call $rpop
 688         set_local $esi
 689         br $next
 690       end ;; op0
 691         get_local $esi
 692         call $sys_reflect
 693         br $bye
 694       end ;; default
 695         get_local $esi
 696         call $rpush
 697         get_local $eax
 698         set_local $esi
 699         br $next
 700     end ;; execloop
 701     end ;; nextl
 702     end ;; bye
 703     i32.const 14340
 704     get_local $here
 705     i32.store
 706     i32.const 14352
 707     get_local $stringbelt_tail
 708     i32.store
 709     i32.const 14356
 710     get_local $stringbelt_head
 711     i32.store
 712     i32.const 14360
 713     get_local $wordbelt_tail
 714     i32.store
 715     i32.const 14364
 716     get_local $wordbelt_head
 717     i32.store
 718     i32.const 14368
 719     get_local $channel
 720     i32.store
 721     i32.const 0
 722   )
 723 )